Porta parallela - Software ASM - Giobe®2000 - Assembler - Assembly - centronics 378 278 input output epp ecp spp

		Come Funziona Indirizzi Base Area Comunicaz. Bios Registri Livello Hardware Livello BIOS Livello DOS Tecniche d'Interruzione Connettori Cavi Interfaccia Applicazioni Software Applicazioni Hardware Download INDICE
Porta Parallela

Applicazioni Software

PROGETTO n° 12 - 3/7 [128 di 166]

Analisi del Problema · Analisi del Codice · Procedure importanti · Schema interfaccia

Porta Parallela - OUTPUT di Dati a 32 bit - Interfaccia con 4 memorie D-Type '374

Analisi del Codice Sorgente [1 di 2]

	Il compito del programma consiste nel fissare al livello logico desiderato, per un tempo grande a piacere, 32 linee d'uscita, per il controllo di altrettante periferiche di tipo *on-off* (come un relè o un led).
	Il codice assembly del programma è visibile, nella sua totalità, scorrendo con la barra laterale il testo della seguente casella:

Progetto

NB: se il testo nell'Area ti sembra strano
installa il font Giobe.TTF: clicca qui!!

PAGE 66,132
TITLE** PROGRAMMA di GESTIONE di programmi ASSEMBLER  tipo COM  (ottobre 2003)
SUBTTL ** TUTORIAL ASSEMBLY  --  www.giobe2000.it   --    by ing. Giorgio OBER
;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³ NOME        : Out32Lpt.ASM                                                ³
;³ AUTORE      : Giorgio OBER                                                ³
;³ VERSIONE    : ottobre 2003                                                ³
;³ DESCRIZIONE : Gestione  di una PORTA PARALLELA a basso livello, al fine di³
;³               controllare 32 linee d'uscita.                              ³
;³ ÚÄÄÄÄÄÄÄÄÄÄ¿ -------------------------------------------------------------³
;³ ³°°°°°°°°°°³ Se si lavora con i Sistemi Operativi Win2000, Win NT o WinXP ³
;³ ³°°°NB !!°°³ bisogna prima installare il Driver Configura_LPT1; scaricalo ³
;³ ³°°°°°°°°°°³ a:   http://www.giobe2000.it/consigli/Scarica_VediLPT_XP.htm ³
;³ ÃÄÄÄÄÄÄÄÄÄÄ´ -------------------------------------------------------------³
;³ ³°°°°°°°°°°³ Se si lavora con i Sistemi Operativi Win2000, Win NT o WinXP ³
;³ ³°°°NB !!°°³ la SHELL DOS deve essere a "Pieno Schermo" (l'esecuzione  in ³
;³ ³°°°°°°°°°°³ "finestra DOS" non produce effetto sulla Stampante)          ³
;³ ÃÄÄÄÄÄÄÄÄÄÄ´ -------------------------------------------------------------³
;³ ³°°°°°°°°°°³ In ogni caso PRIMA DI OGNI SESSIONE DOS Š necessario eseguire³
;³ ³°°°NB !!°°³ il programma Config_LPT1.EXE in ambiente Windows per attivare³
;³ ³°°°°°°°°°°³ la visibilit… dei driver installati con Configura_LPT1 !!!!! ³
;³ ÀÄÄÄÄÄÄÄÄÄÄÙ -------------------------------------------------------------³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
; COSTANTI DEFINITE PER IL PROGRAMMA:
        PRNdato EQU  378H     ;Registro   dei   DATI ( USCITA )
        PRNcomd EQU  37AH     ;Registro di CONTROLLO ( USCITA )

; MACRO UTILIZZATE DAL PROGRAMMA:
        if1     ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
         include  GIOBE.MAC ;(C:\ARCH-LAB\BIN\GIOBE.MAC);³
        endif   ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÚÄÄÄÄ¿ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURE ESTERNE³NEAR³UTILIZZATE dal PROGRAMMA (dalla LIBRERIA GIOBE.LIB~)³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÀÄÄÄÄÙÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        EXTRN    CambiaCol:NEAR
        EXTRN      SET_cur:NEAR
        EXTRN      VIA_cur:NEAR
        EXTRN      RIP_cur:NEAR
        EXTRN      KEYwait:NEAR
        EXTRN      BIOSmsg:NEAR
        EXTRN      Byt2Asc:NEAR
        EXTRN       RAMcls:NEAR
        EXTRN       RAMchr:NEAR
        EXTRN       RAMcur:NEAR
        EXTRN       RAMmes:NEAR
        EXTRN       RIEMPI:NEAR
        EXTRN       RAMpiu:NEAR

; DICHIARAZIONI PER I PROGRAMMI ESTERNI:
        PUBLIC  ATTRIB
        PUBLIC  Out32Lpt

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³DEFINIZIONE DEL SEGMENTO DEL CODICE                                        ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
_prog   SEGMENT BYTE PUBLIC 'CODE'
        ASSUME  CS:_prog,DS:_prog

ORG     0100H
INIZIO: JMP     Out32Lpt

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³AREA DESTINATA AI DATI DEL PROGRAMMA                                       ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
ATTRIB  DB   1FH
Dato_32 DD     0
TESTO1  DB   "Erogazione di un dato a 32 bit sulla porta parallela",00H
TESTO2  DB   "TUTORIAL ASSEMBLY  ---  www.Giobe2000.it  ---",00H
TESTO3  DB   "Quit",00H

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³  AREA DESTINATA ALLE PROCEDURE DEL PROGRAMMA                              ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA  : DeskTop                                                       ³
;³DESCRIZIONE: Procedura che inizializza completamente il  piano  di  lavoro.³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
DeskTop:CALL    RAMcls        ;Pulisce lo schermo e inizializza il segmento
                              ;dedicato alla RamVideo (ES=0B800H)
        CALL    VIA_cur       ; Rende il  cursore invisibile
        M_COLOR  71H          ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
        MOV     AL,"°"        ;³                                             ³
        CALL    RIEMPI        ;³                                             ³
      RAMrepC 80," ", 0, 0,30H;³                                             ³
      RAMrepC 80," ",24, 0,30H;³                                             ³
      RAMcol  TESTO1, 0,10,3FH;³Organizza il piano di presentazione          ³
      RAMcol  TESTO2,24,10,3FH;³                                             ³
      RAMcol  TESTO3,24,73,30H;³                                             ³
        RAM_cur 24,73         ;³                                             ³
        M_COLOR 3FH           ;³                                             ³
        MOV     AL,"Q"        ;³                                             ³
        CALL    RAMchr        ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA  : Out32bit                                                      ³
;³DESCRIZIONE: Procedura che provvede a fissare sulle 4  memorie  74LS374 il ³
;³             dato a 32 predisposto nei registri BX,AX (high,low).          ³
;³             In pratica i 4 bytes predisposti sulla porta 0378H (copia  ri-³
;³             spettivamente di AL, AH, BL e BH) vengono smistati in sequenza³
;³             sulle rispettive memorie (numerate con 0, 1, 2 e 3)           ³
;³                                                                           ³
;³             ÚÄ[037AH/027AH - PORTA d'USCITA dei COMANDI]ÄÄÄÄÄÄÄÄÄÄÄÄÄ¿    ³
;³             ³       ³ * ³ * ³ * ³ * ³Out³Out³Out³Out³                ³    ³
;³             ³non    ÀÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÙ                ³    ³
;³             ³disponib.ÁÄÄÄÁÄÄÄÁÄÄÄÙ   ³   ³   ³   ³                  ³    ³
;³             ³pin 17 NegatoÄÄÄnon usatoÙ   ³   ³   ³                  ³    ³
;³             ³pin 16 ÄÄÄÄ[enable Decoder]ÄÄÙ   ³   ³                  ³    ³
;³             ³pin 14 NegatoÄÄÄÄÄÄÄÄÄÄÄÄÄÄ[InB]ÄÙ   À[InA]Äpin 1 Negato³    ³
;³             ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ    ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Out32bit:PUSH   CS            ;¿Prepara il puntatore  ES:DI = CS:Dato_32  alla
        POP     ES            ;³zona destinata  a  memorizzare il dato binario
        LEA     DI,Dato_32    ;Ùa 32 passato in ingresso in BX,AX
        CLD                   ;¿Memorizza in  sequenza  i  4  bytes, dal  meno
        STOSW                 ;³significativo  (disponibile  in  AL)  al   pi—
        MOV     AX,BX         ;³significativo (disponibile in BH), con l'aiuto
        STOSW                 ;³della  potente  STOSW (Store String Word)  che
                              ;Ùprovvede alle operazioni: ES:[DI]<AX e DI=DI+2
        LEA     DI,Dato_32    ;¿
        MOV     CX,4          ;³Ú[opzionale]ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
Out_0:  MOV     DL,36         ;³³ Provvede alla stampa a video dell'informa- ³
        MOV     AL,4          ;³³ zione (4 bytes) che sta per essere spedita ³
        SUB     AL,CL         ;³³ al  registro  DATI  della porta  parallela ³
        ADD     AL,AL         ;³ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        ADD     DL,AL         ;³
        M_CURSOR 13,DL        ;³Notare la tecnica per stampare nella corretta
        MOV     AL,ES:[DI]    ;³sequenza i 4 bytes, dal meno significativo al
        CALL    Byt2Asc       ;³pi— significativo
        INC     DI            ;³
        LOOP    Out_0         ;Ù
                              ;¿Ricarica il puntatore alla zona  contenente il
        LEA     DI,Dato_32    ;³il dato binario a 32 da  spedire  in  sequenza
                              ;Ùsul Registro DATI  0378H della porta parallela
        MOV     DX,PRNdato    ; Punta il  Registro DATI 0378H  della parallela
        MOV     CX,4          ; Carica il contatore per il servizio di 4 bytes
Out_1:  MOV     AL,ES:[DI]    ;¿Eroga in stretta sequenza i 4 bytes, generando
        OUT     DX,AL         ;³il clock (un breve impulso alto) solo  per  la
        CALL    Clock         ;³memoria interessata dal dato a 8 bit corrente;
        INC     DI            ;³le rimanenti 3 memorie 74LS374 hanno tutte  le
        LOOP    Out_1         ;Ùlinee di clock a livello "0", inattive
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA  : Clock                                                         ³
;³DESCRIZIONE: Genera un impulso alto sulla linea di clock di una sola delle ³
;³             memorie 74LS374 coinvolte nel progetto;  le  rimanenti  hanno ³
;³             tutte le linee di clock a livello basso, disattive.           ³
;³             La memoria interessata dal clock Š quella di ordine CL-n, con ³
;³             n uguale al numero  di  memorie  coinvolte;  naturalmente  il ³
;³             valore di CL deve essere predisposto prima della chiamata.    ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;¿La memoria abilitata Š puntata dall'uscita del
                              ;³decoder 74LS139  puntata  dal  codice  binario
Clock:  ADD     DX,2          ;³applicato sui suoi  ingressi  di  selezione, a
        MOV     AL,4          ;³loro volta fissati dal  valore  dei bit1, bit0
        SUB     AL,CL         ;³(invertiti internamente) predisposto  nel  Re-
                              ;³gistro di CONTROLLO 037AH cioŠ 00 per la prima
                              ;³memoria (in   alto  nello  schema)  e  11  per
                              ;Ùl'ultima (in basso nello schema)
        AND     AL,11111011B  ;¿L'impulso  di  clock Š  creato  effettivamente
        OUT     DX,AL         ;³forzando prima a "0"  e  poi a "1" il bit2 del
        OR      AL,00000100B  ;³medesimo registro; in  questo  modo si abilita
        OUT     DX,AL         ;³il decoder creando un impulso basso sull'usci-
        SUB     DX,2          ;³ta selezionata e il desiderato impulso alto di
        RET                   ;Ùclock sulla memoria, per effetto dell'inverter

;°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°
;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
                              ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿³
Out32Lpt proc   NEAR          ;³      AREA DEDICATA AL MAIN PROGRAM         ³³
                              ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;¿Mette le  memorie  74LS374  in  condizione  di
        MOV     DX,PRNcomd    ;³attesa predisponendo il bit2 del  Registro  di
        MOV     AL,04         ;³di CONTROLLO 037AH al valore 1 cioŠ ponendo  a
        OUT     DX,AL         ;³"1" tutte  le  uscite  del decoder  74LS139  e
                              ;³quindi a "0" le linee di ckock di tutte e 4 le
                              ;Ùmemorie 74LS374
        CALL    DeskTop       ; Organizza il piano di presentazione
        MOV     AX,2301H      ;¿Prepara il dato a 32 bit da spedire, un byte
        MOV     BX,6745H      ;Ùalla volta, alla porta parallela
                              ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
        CALL    Out32bit      ;³Memorizza il dato a 32 sulle linee di USCITA ³
                              ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
xxx00:  CALL    KEYwait       ;¿Si ferma in attesa della pressione di un tasto
        AND     AL,11011111B  ;³imponendo  il  ritorno  immediato  al  sistema
        CMP     AL,"Q"        ;³operativo se si tratta del tasto "Q"
        JZ      _OUT          ;³(cosa non strettamente necessaria..)
        JMP     SHORT xxx00   ;Ù
                              ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
_OUT:   PUSH    AX            ;³Torna al DOS con la memoria liberata e con la³
        CALL    RIP_cur       ;³chiusura di tutti i file; cede  il  controllo³
        MOV     DH,23         ;³al processo padre (generalmente COMMAND.COM);³
        MOV     DL,0          ;³il valore posto eventualmente  in AL prima di³
        CALL    SET_cur       ;³uscire pu• essere testato in  uscita  con  la³
        POP     AX            ;³funzione 4DH o mediante la lettura della  va-³
        MOV     AH,4CH        ;³riabile DOS "ERRORLEVEL"                     ³
        INT     21H           ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
Out32Lpt ENDP                 ;³Chiusura standard del codice                 ³
_prog   ENDS                  ;ÃÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ´
        END INIZIO            ;³Chiusura del segmento di codice e conclusione³
                              ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

La lettura del sorgente può essere operata anche in Ambiente Assembler (disponibile sul Sito accedendo a questa pagina); se hai già provveduto alla sua installazione scarica il sorgente del progetto direttamente nella cartella C:\Arch-Lab\Lavoro (scegliendo il pulsante di opzione "Salva" e, come destinazione, seleziona la cartella che ti ho appena suggerito).

Ricorda: se fai click sull'icona a sinistra si apre l'Ambiente Assembly e puoi entrare in Ambiente on-line.
Scegli il pulsante di opzione "Aprire il file" o "Esegui l'applicazione" e conferma con OK.
NB: alcuni gestori di protezione (per esempio SP2 di WinXP) non ti consentono questa operazione:
in questo caso scrivi c:\arch-lab\bin\sys\assembler.pif direttamente nel campo indirizzo del Browser

Nella shell DOS aperta (o a pieno schermo) puoi iniziare una sessione di lavoro digitando MACRO Out32Lpt /e (con gli spazi al posto giusto !!) e conferma con Invio.

	Porta Parallela			PROGETTO n° 12 - 3/7
	128 di 166

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166

Parallela »